học power bi hàm YTD

Power BI Day 17: Tìm hiểu về cách sử dụng hàm YTD

Ngày đăng: 12/02/2022

Trong bài học Power BI Day 17 hôm nay, chúng mình sẽ cùng tìm hiểu về cách sử dụng hàm YTD. Một yêu cầu phổ biến trong các doanh nghiệp là tính toán số đo từ đầu năm/ quý/ tháng đến thời điểm làm báo cáo. Bài thực hành sau đây với bộ dữ liệu Adventurework sẽ giải quyết bài toán đó!

Tất cả các phép tính thời gian có thể được thực hiện bằng cách sử dụng hàm CALCULATE thông thường với hàm time intelligence hoặc với một trong các hàm TOTAL như TOTALYTD.

Các hàm TOTAL chỉ là các “phiên bản” cú pháp của CALCULATE. Mình thích sử dụng hàm CALCULATE hơn do việc sử dụng CALCULATE làm cho logic công thức rõ ràng hơn và nó cung cấp tính linh hoạt hơn so với các hàm TOTAL.

Tuy nhiên, các công thức sử dụng hàm TOTAL được đánh dấu là (2) trong các ví dụ sau trả về giá trị giống hàm CALCULATE. Mục đích của việc hiển thị này chỉ để cho thấy rằng chúng trả về các giá trị giống như phiên bản CALCULATE.

Tổng số từ đầu năm đến nay – Hàm YTD

Dữ liệu tổng hợp từ đầu năm đến nay bắt đầu từ ngày 1 tháng 1 của năm, như được hiển thị trong hình dưới đây

hàm YTD

Sales YTD (simple) hiển thị giá trị cho bất kỳ khoảng thời gian nào, trong khi Sales YTD và Sales YTD (2) ẩn kết quả sau khoảng thời gian cuối cùng với dữ liệu.

Measure trong bảng Sales table

Sales YTD (simple) :=

CALCULATE (

[Sales Amount],

DATESYTD ( 'Date'[Date] )

)

DATESYTD trả về tập hợp ngày từ ngày đầu tiên của năm hiện tại cho đến ngày cuối cùng hiển thị trong filter context. Do đó, Sales YTD (simple) hiển thị dữ liệu ngay cả cho các ngày trong tương lai trong năm. Chúng ta có thể lược bỏ các giá trị tương lai đó bằng cách khai báo biến ShowValueForDates, công thức chỉ được thực hiện khi ShowValueForDates trả về TRUE.

ShowValueForDates :=

VAR LastDateWithData =

CALCULATE (

MAX ( 'Sales'[Order Date] ),

REMOVEFILTERS ()

)

VAR FirstDateVisible =

MIN ( 'Date'[Date] )

VAR Result =

FirstDateVisible <= LastDateWithData

RETURN

Result

Measure trong bảng Sales table

Sales YTD :=

IF (

[ShowValueForDates],

CALCULATE (

[Sales Amount],

DATESYTD ( 'Date'[Date] )

)

)

Nếu báo cáo dựa trên năm tài chính không tương ứng với năm dương lịch, hàm DATESYTD yêu cầu một đối số bổ sung để xác định ngày cuối cùng của năm tài chính. Lấy ví dụ, báo cáo trong hình dưới đây.

hàm YTD

FIGURE 2 Sales Fiscal YTD và Sales Fiscal YTD (2) hiển thị từ đầu năm đến nay dựa trên các năm tài chính.

Phép đo Sales Fiscal YTD chỉ định ngày và tháng cuối cùng của năm tài chính trong đối số thứ hai của DATESYTD. Biện pháp sau đây sử dụng ngày 30 tháng 6 là ngày cuối cùng của năm tài chính. Đối số thứ hai của DATESYTD phải là một giá trị không đổi tương ứng với định nghĩa của năm tài chính trong bảng Date

Measure trong bảng Sales table

Sales Fiscal YTD :=

IF (

[ShowValueForDates],

CALCULATE (

[Sales Amount],

DATESYTD ( 'Date'[Date], "6-30" )

)

)

Hàm TOTALYTD có thể thay thế cho hàm DATESYTD như sau:

Measure trong bảng Sales table

Sales YTD (2) :=

IF (

[ShowValueForDates],

TOTALYTD (

[Sales Amount],

'Date'[Date]

)

)

Measure trong bảng Sales table

Sales Fiscal YTD (2) :=

IF (

[ShowValueForDates],

TOTALYTD (

[Sales Amount],

'Date'[Date],

"6-30"

)

)

Tổng số hàng quý cho đến nay

QTD (quarter to date) tổng hợp dữ liệu từ ngày đầu tiên của quý như hình dưới:

Sales QTD hiển thị số tiền tính đến thời điểm hiện tại, số này để trống cho năm 2009 vì không có dữ liệu trong Q4-2009.

Tổng số đo theo quý tính đến ngày hôm nay được tính bằng hàm DATESQTD như sau:

Measure trong bảng Sales table

Sales QTD :=

IF (

[ShowValueForDates],

CALCULATE (

[Sales Amount],

DATESQTD ( 'Date'[Date] )

)

)

Hàm TOTALQTD có thể thay thế cho hàm DATESQTD:

Measure trong bảng Sales table

Sales QTD (2) :=

IF (

[ShowValueForDates],

TOTALQTD (

[Sales Amount],

'Date'[Date]

)

)

Hãy truy cập vào đây để tham khảo thêm series bài giảng về Power BI.

Trả lời

Email của bạn sẽ không được hiển thị công khai. Các trường bắt buộc được đánh dấu *